CREATE FUNCTION dbo.nvarchar_to_utf8_varbinary(@s nvarchar(max))
RETURNS varbinary(max)
BEGIN
  DECLARE @i int, @l int, @c int, @res varbinary(max)
  SET @res = 0x
  SET @i = 0
  SET @l = DATALENGTH(@s) / 2
  WHILE @i < @l
  BEGIN
    SET @i = @i + 1
    SET @c = UNICODE(SUBSTRING(@s, @i, 1))
    -- just explode if we find anything that looks like a UTF-16 surrogate:
    IF @c BETWEEN 0xD800 AND 0xDFFF
      SET @res = @res + (SELECT 1/0)
    SET @res = @res +
      CASE
        WHEN @c < 0x0080 THEN CAST(@c AS varbinary(1))
        WHEN @c < 0x0800 THEN CAST(0xC080 | ((@c & 0xFC0) * 0x0004) | (@c & 0x003F) AS varbinary(2))
        ELSE CAST(0xE08080 | ((@c & 0xF000) * 0x0010) | ((@c & 0x0FC0) * 0x0004) | (@c & 0x003F) AS varbinary(3))
      END
  END
  RETURN @res
END
GO

SELECT *,
  ISNULL((SELECT CAST(NULL AS varchar(max)) COLLATE Latin1_General_BIN),
    utf8_octets_interpreted_as_cp437) AS cp437_downcast_to_cp1252
FROM (
    SELECT *,
      CAST(CAST(utf8_encoded_in_varbinary AS xml) AS nvarchar(max)) AS round_tripped_through_utf8,
      ISNULL((SELECT CAST(NULL AS varchar(max)) COLLATE SQL_Latin1_General_Cp437_BIN),
        utf8_encoded_in_varbinary) AS utf8_octets_interpreted_as_cp437
    FROM (
        SELECT original_string, dbo.nvarchar_to_utf8_varbinary(original_string) AS utf8_encoded_in_varbinary
        FROM (
          SELECT N'Intel Core™' AS original_string
          UNION ALL SELECT N'FP202W 20”'
          UNION ALL SELECT N'kijken van familiefoto’s'
          UNION ALL SELECT N'benötigen'
          UNION ALL SELECT N'Ladegerät'
        ) AS A
      ) AS A
  ) AS A
GO